Knowledge Base & Discussion Forum

Best way to backup Microsoft Surface Pro Tablet

Discuss technical questions on AhsayACB

Moderator: Support Team

Best way to backup Microsoft Surface Pro Tablet

Postby Anon000 » Wed Sep 24, 2014 5:46 am

We are starting to see more users using Microsoft Surface Pro tablets and we are having issues with our backup client (6.15.0.0) being able to successfully complete backups due to the tablet being in sleep mode or not connected to the internet. Is there a recommended way to backup Tablets or mobile devices using Ahsay? We have tried using CDP but the backup fails due to no network connectivity. Thanks in advance.

ACB Version= 6.15.0.0
OBS Version= 6.15.0.0
Anon000
 
Posts: 6
Joined: Thu Mar 13, 2014 1:23 am

Re: Best way to backup Microsoft Surface Pro Tablet

Postby PG » Fri Sep 26, 2014 8:50 am

a 'Dirty hack' would be a pre-command to disable sleep mode during the backup and post-command to re-enable on completion

Pre-Command to disable
powercfg -change -standby-timeout-dc 0

post-command to change to 5mins
powercfg -change -standby-timeout-dc 5
PG
 
Posts: 1023
Joined: Thu Feb 18, 2010 5:57 am

Re: Best way to backup Microsoft Surface Pro Tablet

Postby Anon000 » Wed Oct 01, 2014 12:51 am

Thanks PG, good suggestion. What I ended up doing is modifying the "RunBackupSet.bat" and adding the script in a scheduled task that will run when the user unlocks the tablet because more than likely the user will have network connectivity when using the device. Below is the modified script I used in case anyone is looking to do the same. This seems to be working well so far. FYI the timeout command only works in Windows VIsta and above.

Code: Select all
if not "%minimized%"=="" goto :minimized
set minimized=true
start /min cmd /C "%~dpnx0"
goto :EOF
:minimized
rem Anything after here will run in a minimized window
timeout /T 15
@ECHO OFF
REM ##################  RunBackupSet.bat  ######################################
REM # You can use this batch to run any of your backup sets from the           #
REM # command line. Just customize the "User Defined Section" below with your  #
REM # values for your backup action.                                           #
REM ############################################################################

REM ####################  Start: User Defined Section  #########################

REM -------------------------------  BACKUP_SET  -------------------------------
REM | The name or ID of the backup set that you want to run                    |
REM | If backup set name is not in English, please use BackupSetID             |
REM | e.g. SET BACKUP_SET="1119083740107"                                      |
REM |  or  SET BACKUP_SET="FileBackupSet-1"                                    |
REM |                                                                          |
REM | You can leave this parameter blank if you are using ACB or have only 1   |
REM | backup set.                                                              |
REM ----------------------------------------------------------------------------
SET BACKUP_SET=""

REM -------------------------------  BACKUP_TYPE  ------------------------------
REM | Set backup type. You don't need to change this if you are backing up a   |
REM | file backup set.                                                         |
REM | Options available: FILE/DATABASE/DIFFERENTIAL/LOG                        |
REM | e.g. SET BACKUP_TYPE="FILE"          for file backup                     |
REM |  or  SET BACKUP_TYPE="DATABASE"      for Full database backup            |
REM |  or  SET BACKUP_TYPE="DIFFERENTIAL"  for Differential database backup    |
REM |  or  SET BACKUP_TYPE="LOG"           for Log database backup             |
REM |                                                                          |
REM | For MSExchange 2010 BackupSet                                            |
REM | e.g. SET BACKUP_TYPE="DATABASE"      for Full database backup            |
REM |  or  SET BACKUP_TYPE="DIFFERENTIAL"  for Differential database backup    |
REM |  or  SET BACKUP_TYPE="LOG"           for Incremental database backup     |
REM |  or  SET BACKUP_TYPE="COPY"          for Copy database backup           |
REM ----------------------------------------------------------------------------
SET BACKUP_TYPE="FILE"

REM ------------------------------  SETTING_HOME  ------------------------------
REM | Directory to your setting home. Default to                               |
REM | "C:\Documents and Settings\USER\.obm" when not set.                      |
REM | e.g. SET SETTING_HOME="C:\Documents and Settings\John\.obm"              |
REM ----------------------------------------------------------------------------
SET SETTING_HOME=""

REM -------------------------------  DELTA_MODE  -------------------------------
REM | Set In-File Delta mode.                                                  |
REM | Options available: Incremental/Differential/Full (I/D/F)                 |
REM | e.g. SET DELTA_MODE="I"   for Incremental In-file delta backup           |
REM |  or  SET DELTA_MODE="D"   for Differential In-file delta backup          |
REM |  or  SET DELTA_MODE="F"   for Full File backup                           |
REM |  or  SET DELTA_MODE=""    for using backup set in-file delta setting     |
REM ----------------------------------------------------------------------------
SET DELTA_MODE=""

REM -------------------------------  DEBUG_MODE  -------------------------------
REM | Set Debug mode.                                                          |
REM | Options available: DEBUG/NO-DEBUG                                        |
REM | e.g. SET DEBUG_MODE="DEBUG"                                              |
REM |  or  SET DEBUG_MODE="NO-DEBUG"                                           |
REM ----------------------------------------------------------------------------
SET DEBUG_MODE="NO-DEBUG"

REM ####################  END: User Defined Section  ###########################

SET APP_HOME=..
SET JAVA_HOME=%APP_HOME%\jvm
SET JAVA_EXE=%JAVA_HOME%\bin\java.exe
SET JAVA_OPTS=-Xms128m -Xmx768m -Dsun.java2d.noddraw
SET JAVA_LIB_PATH=-Djava.library.path=%APP_HOME%\bin
SET PATH=%JAVA_HOME%\bin;%PATH%
SET CLASSPATH=%APP_HOME%\bin;%APP_HOME%\bin\obc.jar;%APP_HOME%\bin\obc-lib.jar

SET "DEP_LIB_PATH=X64"
IF "%PROCESSOR_ARCHITECTURE%"=="x86" (
  SET "DEP_LIB_PATH=X86"
)
SET PATH=%CD%\%APP_HOME%\bin\%DEP_LIB_PATH%;%PATH%

REM #############################################################################
ECHO -
ECHO APP_HOME=%APP_HOME%
ECHO SETTING_HOME=%SETTING_HOME%
ECHO JAVA_HOME=%JAVA_HOME%
ECHO JAVA_EXE=%JAVA_EXE%
ECHO JAVA_OPTS=%JAVA_OPTS%
ECHO JAVA_LIB_PATH=%JAVA_LIB_PATH%
ECHO PATH=%PATH%
ECHO CLASSPATH=%CLASSPATH%
ECHO -

ECHO Running Backup Set - '%BACKUP_SET%' ...
@ECHO ON
%JAVA_EXE% %JAVA_LIB_PATH% -cp %CLASSPATH% %JAVA_OPTS% RunBackupSet %APP_HOME% %BACKUP_SET% %BACKUP_TYPE% %SETTING_HOME% %DELTA_MODE% %DEBUG_MODE%
EXIT
Anon000
 
Posts: 6
Joined: Thu Mar 13, 2014 1:23 am


Return to AhsayACB

Who is online

Users browsing this forum: No registered users and 1 guest

Looking for Rbackup Alternative | Vembu Alternative | Novastor Alternative | Asigra Alternative | BackupAgent Alternative? Try our product.


A wholly owned subsidiary of Ahsay Backup Software Development Company Limited  [HKEx Stock Code: 8290]